# fh hn   kr
set title "Van-der-Waals Zustandsgleichung CO2"
set xlabel "Molvolumen Vm / l "
set dummy Vm
set grid
set samples 1000
set xrange [0:1.]
set ylabel "Druck p / bar"
p_max = 100.
set yrange [0:p_max]
#
### a in Pa * (m^3/mol)^2 * 1.e6 --> Pa * (lit./mol)^2 
#
a=3.656e-1  * 1.e6
#
### b in m^3 /mol * 1000.  --> lit./mol
#
b=4.282e-5  * 1000.
#
### Rm in Pa * m^3/K * 1000. --> Pa *lit./K
Rm=8.3144 * 1000.
#
Vmk = 3. * b
pk  = 1.E-5* a / (27*b**2)
Tk  =   8. * a / (27*b*Rm)
#
### P in bar !! , Vm in Liter !!
#
p(Vm,T)=1.e-5*(Rm*T/(Vm-b)-a/Vm**2)
set arrow 1 from b,0 to b,p_max nohead linetype 8
#
## Dampfdruck bei 273 K (47 bar) /293 K (63.4  bar), V1 u. V2 num. bestimmt 
#
set arrow 2 from 0.0771,p(0.0771,273.) to 0.307 , p(0.0771 ,273.) nohead linetype 2
set arrow 3 from 0.092 ,p(0.092 ,293.) to 0.2025, p(0.092 ,293.)  nohead linetype 3
set arrow 4 from Vmk   ,1.05*pk        to Vmk   , pk                     linetype 4
set label 1 "K" at Vmk ,1.05*pk
#
plot p(Vm,263.),p(Vm,273),p(Vm,293.),p(Vm,304.2),p(Vm,313.),p(Vm,373.)