#############################################################
# Physik MFT/MI FH HN K, Rauschnabel               12/98    #
# Beugung am Spalt .. Gitter                                #
#############################################################
set dummy a
set grid
set xlabel "Alpha   /rad" 
set xrange [-0.02 : 0.02]
set samples 1999
set ylabel "Intensität     /w.E." 
set yrange [0 : 110]
#
b   = 0.1e-3
lam = 400.e-9
I0  = 100.
set title "Beugung am Spalt"
#
I(a) = I0 * ( sin( pi*b/lam * sin(a) ) / ( pi*b/lam * sin(a) ) )**2
#
plot I(a)
#
pause -1 "Weiter mit Doppelspalt ..."
#
set title "Beugung am Doppelspalt"
g  = 0.323e-3
Interf(p,a) = ( sin( p * pi*g/lam * sin(a) ) / ( p*sin( pi*g/lam * sin(a) ) ) )**2
#
plot I(a) * cos( pi*g/lam * sin(a) )**2 , I(a)
#
pause -1 "Weiter mit Vierfachspalt ..."
#
set title "Beugung am Vierfachspalt"
#
plot I(a) * Interf(4,a) , I(a)
#
pause -1 "Weiter mit Achtfachspalt ..."
#
set title "Beugung am Achtfachspalt"
#
plot I(a) * Interf(8,a) , I(a)
#
pause -1 "Weiter mit Gitter, p = 40 ..."
#
set title "Beugung am Gitter, p = 40"
#
plot I(a) * Interf(40,a) , I(a)
#