#################################################################
# Hochschule Heilbronn                              kr  5/2006  #
# Physik für Ingeniuere                                         # 
# 4.1.2 Gedämpfter Harmonischer Oszillator                      #            
# 4.1.2.1 Geschwindigkeitsunabhängige Reibung                   # 
# Harmonischer Oszillator mit aeusserer Reibung                 #     
# ho_reibung_v_unabhaengig.plt                                  #
#################################################################
#
reset
# unset mouse
#
set dummy t
set grid
set key
set samples 1000
set notime
set xrange [0 : 3 ]
set yrange [-.33:.33]
set xlabel "Zeit t /s"
set ylabel "x(t) /m"
set title "Harmonischer Oszillator mit aeusserer Reibung"     
set xzeroaxis lt -1   
#
x0 = 0.31
s0 = 0.02
T  = 0.5
#
om = 2.*pi/T
TH = T/2.
#
s_0(t)   = s0*(-1.)**int(t/TH)
Null1(t) = (int(t/TH)%2)==0?s0:(1/0)
Null2(t) = (int(t/TH)%2)==1?-s0:(1/0)
A(t)     = x0-s0-2.*s0*int(t/TH) 
x1(t)    = A(t)*cos(om*t)+ s_0(t)
x(t)     = t < TH*ceil((x0-s0)/(2.*s0))  ? x1(t) : x1( TH*ceil((x0-s0)/(2.*s0)) )
#
eps=.5*TH
#
# Bem.: In Vers. 3.7 geht "heads" (Doppelpfeil) noch nicht ! Verwende "nohead" (keine Pfeilspitze)
#
set arrow 1 from 0*TH+eps, s0-A(0*TH) to 0*TH+eps, s0+A(0*TH) nohead lt 3
set arrow 2 from 1*TH+eps,-s0-A(1*TH) to 1*TH+eps,-s0+A(1*TH) nohead lt 1
set arrow 3 from 2*TH+eps, s0-A(2*TH) to 2*TH+eps, s0+A(2*TH) nohead lt 3
set arrow 4 from 3*TH+eps,-s0-A(3*TH) to 3*TH+eps,-s0+A(3*TH) nohead lt 1
set arrow 5 from 4*TH+eps, s0-A(4*TH) to 4*TH+eps, s0+A(4*TH) nohead lt 3
set arrow 6 from 5*TH+eps,-s0-A(5*TH) to 5*TH+eps,-s0+A(5*TH) nohead lt 1
set arrow 7 from 6*TH+eps, s0-A(6*TH) to 6*TH+eps, s0+A(6*TH) nohead lt 3
#
set arrow 8 from 0*TH , s0+A(0*TH)  to 7*TH , s0+A(7*TH) nohead
set arrow 9 from 0*TH ,-s0-A(0*TH)  to 7*TH ,-s0-A(7*TH) nohead
#
plot Null1(t) notit with lines lt -1,Null2(t)notit with lines lt -1, x(t) lt 10