#################################################################
# Hochschule Heilbronn                              kr  5/2006  #
# Physik für Ingeniuere                                         # 
# 4.1.1 Harmonischer Oszillator                                 #            
# Beispiel fuer die Bestimmung der Parameter einer Schwingung   # 
# Harmonischer Oszillator mit Anfangbedingungen                 #     
# ho_anfangsbed_bsp.plt                                         #
#################################################################
#
reset
# unset mouse
#
set dummy t
set title "Harmonischer Oszillator" 0,0
set xlabel "Zeit t /s" 0,0
set grid
set xzeroaxis lt -1   
#
tmax = 1.6
#
set xrange [0.:tmax]
set xtic 0 , tmax/8
#
# Anfangsbed. gegeben : x0 , v0 !
#
x0 =  0.01361
v0 = -0.1872
#             >>>  x0 =  0.0136079 
#             >>>  v0 = -0.187154 
#
#  Masse-Feder-Pendel
#
m = 10.e-3
c = 0.49
#
om0  = sqrt(c/m)
phi0 = atan(- v0 / (om0*x0) )
A    = x0 / cos(phi0)
#
# Funktion x(t)
#
set ylabel "Auslenkung x(t) /m" 0,0
x(t) = A * cos( om0 * t + phi0 )
set yrange [-1.1*A:1.1*A]
plot x(t)
#
pause -1 "Weiter mit Geschwindigkeit!"
#
#
# Funktion v(t)
#
set ylabel "Geschwindigkeit v /(m/s)" 0,0
set yrange [-1.1*A*om0:1.1*A*om0]
v(t) = -A * om0 * sin( om0 * t + phi0 )
#
plot v(t)
#
pause -1 "Weiter mit : Vergleich versch. Ansätze"
#
set ylabel "Auslenkung x(t) /m" 0,0
set yrange [-1.1*A:1.1*A]
plot x(t),A*sin(om0*t+phi0+pi/2.),x0*cos(om0*t)+(v0/om0)*sin(om0*t)
#