########################################################################
# Hochschule Heilbronn                              kr  6/2006         #
# Physik für Ingenieure                                                # 
# 4.1. Schwingungen                                                    #            
# Erzwungene Schwingungen, Resonanz                                    #  
# komplexe Funktion Z(omega) : Ortskurve, Real- u. Imaginärteil,       #
#                              Betrag (Amplitude), Phasenverschiebung  #
#                                                                      #
# erzwungene_schwingungen_komplex.plt                                  #
########################################################################
#
reset
# unset mouse
#
set xzeroaxis lt -1
set yzeroaxis lt -1
set grid
#
#  Erzw. Schwingungen
#
j    = {0.,1.}
WZH  = sqrt(0.5)
#
om0  = 1.
a0   = 0.01
#
# komplexe Fkt. Z(omega)
#
Z(omega,del) = a0 * om0**2  / (om0**2 - omega**2 + j*2.*del*omega)
#
set parametric
set dummy omega
set trange[0:3.*om0]
set label "Re(Z)  /m"  at  0.05,0.005  center
set xtics axis
set xrange [-0.06 : 0.06]
set label "Im(Z)   /m" at -0.015,-0.07 rotate  
set ytics axis
set yrange [-0.11 : 0.01]
set key -0.04,-0.09
#
set multiplot
set title "Erzwungene Schwingungen, Resonanz: Ortskurve in komplexer Ebene" 
set samples 1000
plot real(Z(omega,0.05)),imag(Z(omega,0.05)) title "0.05" , real(Z(omega,0.1)),imag(Z(omega,0.1)) title "0.1" , real(Z(omega,0.2)),imag(Z(omega,0.2)) title "0.2" ,real(Z(omega,WZH)),imag(Z(omega,WZH)) title ".707.."   
#
set function style points
set samples 31
set nokey
plot real(Z(omega,WZH )),imag(Z(omega,WZH )) with points lt 4 pt 4 ps 0.5 
plot real(Z(omega,0.2 )),imag(Z(omega,0.2 )) with points lt 3 pt 4 ps 1.5  
plot real(Z(omega,0.1 )),imag(Z(omega,0.1 )) with points lt 2 pt 4 ps 1.5
plot real(Z(omega,0.05)),imag(Z(omega,0.05)) with points lt 1 pt 4 ps 1.5
#
set nomultiplot
#
# Einstellungen zurücksetzten - reset !!!!!!!!
#
reset
#
#
set title "Erzwungene Schwingungen, Resonanz" 0,0
set grid
set xzeroaxis lt -1
set samples 1000
#
pause -1 "Weiter mit Amplitude"
#
#
# Amplitude: Funktion A(omega)
#
set dummy omega
set xrange [0:3.*om0]
set xlabel "Erreger-Kreisfrequenz omega_E    /(1/s)" 0,0
set ylabel "Amplitude  /m" 
#
A(omega,del) = abs(Z(omega,del))
#
plot A(omega,0.025) title "0.025  ", A(omega,0.050) title "0.050  ", A(omega,0.1) title "0.100  ", A(omega,WZH) title "0.707..", A(omega,2.000) title "2.000  "
#
# Real und Imaginärteil von Z(omega)
#
set ylabel "Z  /m" 
set yrange [-0.12:0.12]
#
#
pause -1 "Weiter mit Realteil, Imaginärteil,Amplitude  D = 0.05"
# 
set title "Erzwungene Schwingungen, Resonanz ;  D = 0.05" 0,0
#
del = 0.05 * om0
plot real(Z(omega,del)) title "Re(Z)" ,imag(Z(omega,del)) title "Im(Z)" ,abs(Z(omega,del)) title "abs(Z)"  
#
#
pause -1 "Weiter mit Realteil, Imaginärteil,Amplitude  D = 0.1"
# 
set title "Erzwungene Schwingungen, Resonanz ;  D = 0.1" 0,0
#
del = 0.1 * om0
plot real(Z(omega,del)) title "Re(Z)" ,imag(Z(omega,del)) title "Im(Z)" ,abs(Z(omega,del)) title "abs(Z)"  
#
pause -1 "Weiter mit Realteil, Imaginärteil,Amplitude  D = 0.2"
# 
set title "Erzwungene Schwingungen, Resonanz ;  D = 0.2" 0,0
#
del = 0.2 * om0
plot real(Z(omega,del)) title "Re(Z)" ,imag(Z(omega,del)) title "Im(Z)" ,abs(Z(omega,del)) title "abs(Z)"  
#
pause -1 "Weiter mit Realteil, Imaginärteil,Amplitude  D = 0.707.."
# 
set title "Erzwungene Schwingungen, Resonanz ;  D = 0.707.." 0,0
#
del = WZH * om0
plot real(Z(omega,del)) title "Re(Z)" ,imag(Z(omega,del)) title "Im(Z)" ,abs(Z(omega,del)) title "abs(Z)"  
#
pause -1 "Weiter mit Phase"
#
# Phasenverschiebung: Funktion phi(omega)
#
set ylabel "Phasenwinkel /Grad" 0,0
set label  "Erreger-Kreisfrequenz omega_E    /(1/s) " at 3,10 right
set yrange [-180.:15.]
set ytics -180,30
set xtics axis
set key 2.5,-20
#
#  atan2 gibt's jetzt in gnuplot .... 
#  atan2(Im,Re)=Re > 0. ? atan(Im/Re) : ( Re<0. ? pi-atan(abs(Im/Re)) : .5*pi) * sgn(Im)                                                                               
#
phi(omega, del) = 180./pi * atan2( imag( Z(omega,del) ) , real( Z(omega,del) ) )
#
# 
set title "Erzwungene Schwingungen, Phasenresonanzfunktion"
#
plot phi(omega,0.025) title "0.025" , phi(omega,0.05) title "0.05" , phi(omega,0.1) title "0.1" , phi(omega,WZH) title "0.707", phi(omega,2.) title "2."
#