########################################################################
# Hochschule Heilbronn                              kr  9/2006         #
# Physik für Ingenieure                                                # 
# 4.1. Schwingungen                                                    #            
# Erzwungene Schwingungen, Einschwingvorgang                           # 
# Anfangsbedingungen: x(0) = 0 , v(0) = 0                              # 
#                                                                      #
# einschwingvorgang.plt                                                #
########################################################################
#
reset
# unset mouse
#
set xzeroaxis lt -1
set yzeroaxis lt -1
set grid
set dummy t
set title "Einschwingvorgang bei erzw. Schwingungen ( x(0) = 0 , v(0) = 0 )" 
set xlabel "Zeit t /s" 0,0
set grid
#
set xrange [0.:20.]
set samples 1000
#
# Kreisfrequenzen (Eigenfreq. und Erregerfreq) sowie Abklingkonstante 
#
om0 =  10.
del =  .2
ome =  50.
#
# Funktionen x(t)
#
fakt= 2.e-3 / 4.e-3
#
omd = sqrt(om0**2 - del**2)
A0  = fakt / sqrt( (om0**2-ome**2)**2 + 4.* del**2 * ome**2 )
#
# Nostalgie: atan2 für Fußgänger
# atan2(Im,Re)=Re > 0. ? atan(Im/Re) : ( Re<0. ? pi-atan(abs(Im/Re)) : .5*pi) * sgn(Im)                                       
#
phi0= atan2( -2.*del*ome , (om0**2-ome**2) )
#
AC  = -A0 * cos(phi0)
AS  = -A0 * ( ome*sin(phi0) -del*cos(phi0) ) / omd
#
phi1= atan2( AS , AC )
#
A1  = (om0 != ome) ? AC / cos(phi1)  : A0
#
x_hom(t)  = A1 * cos( omd*t + phi1 ) * exp(-del*t)
x_part(t) = A0 * cos( ome*t + phi0 ) 
x(t)      = x_hom(t) + x_part(t)
#
set ylabel "Auslenkung x(t) /m" 0,0
plot x_part(t),x_hom(t),x(t) 
#