########################################
# FH HN , Physik f. FT/MI              #
# Energie beim HO                      #
########################## kr     5/96 #
m  =   1.
c  = 100.
h0 =   0.3
g  =   9.81
# -----------------
om = sqrt(c/m)
sd = m*g/c
T  = 2.*pi/om
# -----------------
set title "Masse - Feder -Schwinger"
set dummy t
set nokey
set nolabel
set xrange [ 0 : 3. * T ]
set xlabel " Zeit t (s)"
# -----------------
s(t)      = sd * ( 1. - cos(om*t) )
h(t)      = h0 - s(t)
v(t)      = om * sd * sin(om*t)
E_kin(t)  = 0.5 * m * v(t)**2
E_Sp(t)   = 0.5 * c * s(t)**2
E_Lage(t) = m * g * h(t)
# -----------------
set yrange [0:2.1*sd]
set ylabel " Weg  s  [m]"
plot s(t)
# -----------------
pause -1 " ... weiter : Hoehe"
set yrange [0:1.1*h0]
set ylabel " Hoehe  h  [m]"
plot h(t)
# -----------------
pause -1 " ... weiter : Geschwindigkeit"
set yrange [-1.1*om*sd:1.1*om*sd]
set ylabel " Geschw.  v   [m/s]"
plot v(t)
# -----------------
pause -1 " ... weiter : Energie"
set yrange [0:1.1*m*g*h0]
set ylabel " Energie  [J]"
set label 1 "E_tot"  at 0.50 * T , m*g*h0 * 1.05
set label 2 "E_Lage" at 1.20 * T , E_Lage(1.20*T)
set label 3 "E_Sp"   at 0.70 * T , E_Sp(0.70*T)
set label 4 "E_kin"  at 0.40 * T , E_kin(0.40*T)
plot E_kin(t),E_Sp(t),E_Lage(t),E_kin(t)+E_Sp(t)+E_Lage(t)
# -----------------